Add meson.build files to build with meson

Provide both build systems in parallel for now, to ensure that we work
out all the differences between the two. Some time from now, we'll give
up on autotools.

Meson tends to be faster and probably easier to read/maintain. On my
machine, the full meson configure+build+install takes a little under
half as long as a similar autotools-based invocation.

Building with meson is a two step process. First, configure the build:

  meson build

Then, compile the project:

  ninja -C build

There's some mild differences in functionality between meson and
autotools.  specifically:

1) No singular update-po target. meson only generates individual
update-po targets for each textdomain (of which we have 3).  To make
this easier, there's a build-aux/update-po script which finds all
update-po targets and runs them.

2) No 'make dist' equivalent. Just run 'git archive' to generate a
suitable tarball for distribution.

1 files changed, 66 insertions, 0 deletions

diff --git a/scripts/meson.build b/scripts/meson.build
new file mode 100644
index 00000000..1fe3fb78
--- /dev/null
+++ b/scripts/meson.build
@@ -0,0 +1,66 @@
+scripts = [
+  'makepkg-template.pl.in',
+  'makepkg.sh.in',
+  'pacman-db-upgrade.sh.in',
+  'pacman-key.sh.in',
+  'pkgdelta.sh.in',
+  'repo-add.sh.in'
+]
+
+library_files = [
+  'library/human_to_size.sh',
+  'library/size_to_human.sh',
+]
+
+SCRIPT_EDITOR = find_program(configure_file(
+  input : join_paths(meson.source_root(), 'build-aux/edit-script.sh.in'),
+  output : 'edit-script.sh',
+  configuration : substs))
+
+m4_edit = generator(
+  M4,
+  arguments : ['-P', '-I', meson.current_source_dir(), '@INPUT@'],
+  output : '@PLAINNAME@',
+  capture : true)
+
+foreach script : scripts
+  custom_target(
+    script,
+    input : m4_edit.process(script),
+    command : [ SCRIPT_EDITOR, '@INPUT@', '@OUTPUT@', '0755'],
+    output : script.split('.')[0],
+    depend_files : library_files,
+    install : true,
+    install_dir : get_option('bindir'))
+endforeach
+
+foreach symlink : ['repo-remove', 'repo-elephant']
+  meson.add_install_script(MESON_MAKE_SYMLINK,
+                           'repo-add',
+                           join_paths(BINDIR, symlink))
+endforeach
+
+subdir('libmakepkg')
+
+custom_target(
+  'bash_completion',
+  command : [ SCRIPT_EDITOR, '@INPUT@', '@OUTPUT@' ],
+  input : 'completion/bash_completion.in',
+  output : 'pacman',
+  install : true,
+  install_dir : BASHCOMPDIR)
+
+foreach symlink : ['pacman-key', 'makepkg']
+  meson.add_install_script(MESON_MAKE_SYMLINK,
+                           'pacman',
+                           join_paths(BASHCOMPDIR, symlink))
+endforeach
+
+zsh_completion_dir = join_paths(DATAROOTDIR, 'zsh/site-functions')
+custom_target(
+  'zsh_completion',
+  command : [ SCRIPT_EDITOR, '@INPUT@', '@OUTPUT@' ],
+  input : 'completion/zsh_completion.in',
+  output : '_pacman',
+  install : true,
+  install_dir : zsh_completion_dir)