Add meson.build files to build with meson

Provide both build systems in parallel for now, to ensure that we work
out all the differences between the two. Some time from now, we'll give
up on autotools.

Meson tends to be faster and probably easier to read/maintain. On my
machine, the full meson configure+build+install takes a little under
half as long as a similar autotools-based invocation.

Building with meson is a two step process. First, configure the build:

  meson build

Then, compile the project:

  ninja -C build

There's some mild differences in functionality between meson and
autotools.  specifically:

1) No singular update-po target. meson only generates individual
update-po targets for each textdomain (of which we have 3).  To make
this easier, there's a build-aux/update-po script which finds all
update-po targets and runs them.

2) No 'make dist' equivalent. Just run 'git archive' to generate a
suitable tarball for distribution.

1 files changed, 31 insertions, 0 deletions

diff --git a/scripts/libmakepkg/meson.build b/scripts/libmakepkg/meson.build
new file mode 100644
index 00000000..07475b4d
--- /dev/null
+++ b/scripts/libmakepkg/meson.build
@@ -0,0 +1,31 @@
+libmakepkg_modules = [
+  { 'name' : 'integrity',     'has_subdir' : true },
+  { 'name' : 'lint_config',   'has_subdir' : true },
+  { 'name' : 'lint_package',  'has_subdir' : true },
+  { 'name' : 'lint_pkgbuild', 'has_subdir' : true },
+  { 'name' : 'source',        'has_subdir' : true },
+  { 'name' : 'srcinfo',                           },
+  { 'name' : 'tidy',          'has_subdir' : true },
+  { 'name' : 'util',          'has_subdir' : true },
+]
+
+mkdir_p = 'mkdir -p $DESTDIR/@0@'
+
+foreach module : libmakepkg_modules
+  custom_target(
+    'libmakepkg_@0@'.format(module['name']),
+    command : [ SCRIPT_EDITOR, '@INPUT@', '@OUTPUT@' ],
+    input : '@0@.sh.in'.format(module['name']),
+    output : '@BASENAME@',
+    install : true,
+    install_dir : join_paths(get_option('datadir'), 'makepkg'))
+
+  if module.get('has_subdir', false)
+    subdir(module['name'])
+    path = join_paths(get_option('prefix'),
+                      get_option('datadir'),
+                      'makepkg',
+                      module['name'])
+    meson.add_install_script('sh', '-c', mkdir_p.format(path))
+  endif
+endforeach